Часть третья: Творим!

  Bet2.X = 320
  Bet2.SpeedX = 0

  Ball.X = 320
  Ball.Y = 240
  Ball.SpeedY = -5
  Ball.SpeedX = GetRandomSpeedX
End Sub

Здесь используется дополнительная функция GetRandomSpeedX. Она возвращает случайное приращение по оси X, колеблющееся от -5 до 5. Вот как она описывается.

Private Function GetRandomSpeedX() As Integer
  Randomize
  GetRandomSpeedX = Int(Rnd * 10) - 5
End Function

Теперь, функция, которая инициализирует карту. Ее нужно вызывать только один раз, когда загружается уровень. Вы можете сами поэкспериментировать, дописыая новые уровни.

Public Sub LoadMap(ByVal Level As Integer)
  Dim i As Integer
  Select Case Level
  Case 1 'Всего лишь две вертикальные стенки по бокам
    For i = 0 To 11
      Map(i, 0) = 1
      Map(i, 15) = 1
    Next i
  End Select
End Sub

Мы всего-лишь задали матрицу. Нам еще понадобится процедура, которая будет рисовать карту каждый виток цикла по этой матрице.

Public Sub DrawMap()
  Dim i As Integer, j As Integer
  For i = 0 to 11
    For j = 0 to 15
      If Map(i,j)=1 then
        ' Если встретили в матрице значение 1, переводим на это место на экране красный блок
        rc.Top = 0
        rc.Left = 102
        rc.Right = rc.Left + 40
        rc.bottom = 40
        Call lpDDSBack.BltFast(40 * j, 40 * i, lpDDSPic, rc, DDBLTFAST_WAIT Or DDBLTFAST_SRCCOLORKEY)
      End If
    Next j
  Next i
End Sub

Теперь, процедура, которая будет рисовать биты. В параметре ей указывается какая бита будет рисоваться, 1-нижняя, 2-верхняя

Public Sub DrawBet(ByVal Num As Integer)
  Dim BY As Integer, BX As Integer 

  If Num = 1 Then
    rc.Left = 0
    Bet1.X = Bet1.X + Bet1.SpeedX  'Новая координата X
    If Bet1.X + 80 > 600 Then Bet1.X = 600 - 80  'Проверяем на боковые стенки, которые д. б. всегда
    If Bet1.X < 40 Then Bet1.X = 40
    BX = Bet1.X
    BY = 460
  Else
    ' Поставьте здесь ремарку пока не напишете функцию DoBetAI
    DoBetAI  'Вычисляем приращение по X биты компьютера

    rc.Left = 142
    Bet2.X = Bet2.X + Bet2.SpeedX
    If Bet2.X + 80 > 600 Then Bet2.X = 600 - 80
    If Bet2.X < 40 Then Bet2.X = 40
    BX = Bet2.X
    BY = 0
  End If 

  'Заполняем недостающие элементы структуры RECT и рисуем биту на заднем буфере
  rc.Top=0
  rc.bottom = rc.Top + 20
  rc.Right = rc.Left + 80
  Call lpDDSBack.BltFast(BX, BY, lpDDSPic, rc, DDBLTFAST_WAIT Or DDBLTFAST_SRCCOLORKEY)
End Sub

Отлично, теперь "приделаем" нашей нижней бите управление. Доведите процедуру обработки события формы frmBall_KeyDown до следующего состояния, а затем допишите обработку события frmBall_KeyUp:

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
  Select Case KeyCode
  Case vbKeyEscape 'Выход
    bEnd = True
  Case vbKeyLeft 'Управление первого игрока
    Bet1.SpeedX = -5
  Case vbKeyRight
    Bet1.SpeedX = 5
  End Select
End Sub

Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
  Bet1.SpeedX = 0
End Sub

Добавим в регион 1 следующее:

mdlBall.Reset
mdlBall.LoadMap 1

А в регион 2 это:

mdlBall.DrawMap
mdlBall.DrawBet 1

Запустите программу. Вы увидите, что уровень уже нарисован и вы можете двигать свою битку в пределах стенок. Эти стенки по определению должны быть всегда, учитывайте это. Выходите из программы как и раньше, с помощью Escape.

Свободный полет

Осталось самое сложное - запрограммировать мячик, чтобы он летал и отскакивал от тех мест, которые в массиве помечены единичкой. Я сделал это вот каким нехитрым образом. Итак, представьте себе двухмерный мячик. В процессе полета он может находиться целиком в одном секторе (каждый сектор - 40*40, если помните, а мяч - 20*20), в двух секторах одновременно, в трех не может, а вот в четырех - запросто. Теперь представьте, что у мячика есть крайние точки, так называемые - "контрольные точки". Можно сказать, что если одна из этих точек находится в каком-то секторе, то некая часть мячика тоже находится в этом секторе. Таким образом, если контрольная точка находится в секторе, который помечен 0, то все нормально, однако, если контрольная точка попадает в сектор с 1, то он уже занят блоком и мячик должен отскочить. В какую сторону? Посмотрите на такой рисунок:

Вы видите на нем четыре контрольных точки, отмеченных красным, а также их координаты в системе координат мяча. Если мяч попал в занятый сектор точкой номер 1, то очевидно, что он стукнулся о преграду, находящуюся сверху него и должен отсочить вниз. Это легко задать формулой SpeedY=-SpeedY. Если "просигналила" точка номер два, то мяч отскакивает влево и т. д. При этом, мяч нужно "отпозиционировать" то-есть поставить просигналившую точку ровно на границу с занятым сектором, чтобы мяч не "залипал" там.

Конечно, для правильного отображения четырех точек явно мало, мяч может уже быть в занятом секторе и ни одна точка не присогналит, поэтому в идеале надо рассматривать каждую точку окружности мяча, лезть в дебри тригонометрии... бррр... Я вас еще не убедил?

Хорош этот способ или нет, решайте сами. По крайней мере он работает.

Теперь функция, которая выдает контрольную точку, если мяч попал в занятый сектор или ноль, если все нормально.

Private Function CheckPoint() As Integer
  Dim Ret As Integer
  Ret = 0
  'Проверяем точки
  If Map(Int((Ball.Y + 10) / 40), Int(Ball.X / 40)) <> 0 Then Ret = 4
  If Map(Int((Ball.Y + 20) / 40), Int((Ball.X + 10) / 40)) <> 0 Then Ret = 3
  If Map(Int((Ball.Y + 10) / 40), Int((Ball.X + 20) / 40)) <> 0 Then Ret = 2
  If Map(Int(Ball.Y / 40), Int((Ball.X + 10) / 40)) <> 0 Then Ret = 1
  CheckPoint = Ret
End Function

Функция будет всегда выдавать только одну точку с приоритетом по часовой стрелке.

Настал момент рисования мяча.

Public Sub DrawBall()
  MoveBall 'Вычисляем новые координаты мяча
  rc.Top = 0
  rc.Left = 81
  rc.bottom = 21
  rc.Right = 102
  ' Рисуем его
  Call lpDDSBack.BltFast(Ball.X, Ball.Y, lpDDSPic, rc, DDBLTFAST_WAIT Or DDBLTFAST_SRCCOLORKEY)
End Sub

Private Sub MoveBall()
  Dim Pt As Integer
  'Делем следующий шаг
  Ball.X = Ball.X + Ball.SpeedX
  Ball.Y = Ball.Y + Ball.SpeedY
  Pt = CheckPoint 'И проеряем, где после этого оказался мяч
  'Проверяем попадание мяча одной из контрольных точек в занятый сектор
  If Pt > 0 Then
    Select Case Pt
    Case 1 'Верх
      Ball.SpeedY = -Ball.SpeedY 'Изменение осевой скорости
      Ball.Y = Int(Ball.Y / 40) * 40 + 40 'Нормализация осевой координаты
    Case 2 'Право
      Ball.SpeedX = -Ball.SpeedX
      Ball.X = Int((Ball.X + 20) / 40) * 40 - 20
    Case 3 'Низ
      Ball.SpeedY = -Ball.SpeedY
      Ball.Y = Int((Ball.Y + 20) / 40) * 40 - 20
    Case 4 'Лево
      Ball.SpeedX = -Ball.SpeedX
      Ball.X = Int(Ball.X / 40) * 40 + 40
    End Select 'Дополнительных точек пока нет
  Else
    'Нижняя ракетка
    If Ball.Y + 20 > 460 Then
       If (Ball.X + 15) >= Bet1.X And (Ball.X + 5) <= (Bet1.X + 80) Then
         'Отбили мяч
         Ball.SpeedY = -Ball.SpeedY
         Ball.SpeedX = GetDirectSpeedX
         Ball.Y = 460 - 20
       Else
         'Мяч упал
         Reset
       End If
     End If
    'Верхняя ракетка
    If Ball.Y < 20 Then
      If (Ball.X + 15) >= Bet2.X And (Ball.X + 5) <= (Bet2.X + 80) Then
        Ball.SpeedY = -Ball.SpeedY
        Ball.SpeedX = GetRandomSpeedX 
        Ball.Y = 20
      Else
        Reset
      End If
    End If
  End If
End Sub

Private Function GetDirectSpeedX() As Integer
  'Направление мяча по X в зависимости от того, каким местом биты отбил его игрок
  GetDirectSpeedX = Int(((Ball.X + 10) - (Bet1.X + 40)) / 8)
End Function

Наконец, последняя функция - вычисление приращения по X ракетки компьютера в зависимости от позиции мяча. Все очень просто. Компьютер всегда старается, чтобы левый и правый край мяча попадал в поле его ракетки.

Private Sub DoBetAI()
  If Ball.X <= Bet2.X + 10 Then Bet2.SpeedX = -5
  If Ball.X + 20 >= Bet2.X + 80 Then Bet2.SpeedX = 5
  If Ball.X > Bet2.X And Ball.X + 20 < Bet2.X + 80 Then Bet2.SpeedX = 0
End Sub

Громкие апплодисменты! Написание модуля завершено. Теперь добавьте в регион две cтроки:

mdlBall.DrawBet 2
mdlBall.DrawBall

И запустите программу (Не забудьте снять ремарку с вызова функции DoBetAI). Работает? Ура!

Надеюсь, теперь вам немного стало ясно, как делаются игрушки на DirectX. Если нет - то это нормально. Просто надо упражняться, упражняться и еще раз упражняться... Не помню кто сказал...

На этом части три пришел конец. В следующей части поговорим об эффектах.

Пример - проект VBPong ~25кб Загрузить

Приятного программирования, Antiloop